/*----------------    FILE HEADER ---------------------------------------
 This file is part of Geoide.
 Copyright (C) 2005-2006 by:
 IDgis B.V.
 http://www.idgis.nl

 This library is free software; you can redistribute it and/or
 modify it under the terms of the GNU Lesser General Public
 License as published by the Free Software Foundation; either
 version 2.1 of the License, or (at your option) any later version.

 This library is distributed in the hope that it will be useful,
 but WITHOUT ANY WARRANTY; without even the implied warranty of
 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
 Lesser General Public License for more details.

 You should have received a copy of the GNU Lesser General Public
 License along with this library; if not, write to the Free Software
 Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307 USA

 Contact:

 Herman Assink
 IDgis bv
 P.O. Box 15
 7450 AA Holten
 The Netherlands
 E-Mail: herman.assink@idgis.nl

 * @version 1.4.0
 * @author IDgis team
 * 
 ------------------------------------------------------------------------*/
import nl.idgis.giclient.gis.Column;
import nl.idgis.giclient.gis.Feature;
import nl.idgis.giclient.webserviceconnector.wfsconnector.FeatureType;
import nl.idgis.giclient.webserviceconnector.wfsconnector.Operation;
import nl.idgis.giclient.geoma.GMLFactory;
import nl.idgis.giclient.geoma.Geometry;
import nl.idgis.giclient.geoma.NullGeometry;
import nl.idgis.giclient.webserviceconnector.wfsconnector.Property;

class nl.idgis.giclient.webserviceconnector.wfsconnector.Insert extends Operation {
    
    function Insert(feature:Feature) {
        super(feature);
    }
    
    function toString():String {
        return "Insert(" + feature.getID() + ")";
    }
    
    function toXML():String {
        var xml:String = "";
        var featureType:FeatureType = feature.getFeatureType();
        var featureTypeName:String = featureType.getName();
        var featureID:String = feature.getID();
        
        xml += "<wfs:Insert handle=\"" + featureTypeName + "/" + featureID + "\" idgen=\"GenerateNew\">\n";
        xml += "    <" + featureTypeName + " gml:id=\"" + featureID + "\">\n";
        
        var properties:Array = featureType.getProperties();
        var property:Property = null;
        var propertyName:String = null;
        var propertyValue:String = null;
        var geometry:Geometry = null;
        for (var i:Number = 0; i < properties.length; i++) {
            property = Property(properties[i]);
            propertyName = property.getName();
            if (property != featureType.getDefaultGeometryProperty()) {
                propertyValue = feature.getColumnValue(propertyName);
                if (propertyValue != null) {
                    
                    xml += "        <" + propertyName + ">" + propertyValue + "</" + propertyName + ">\n";
                }
            } else {
                geometry = feature.getGeometry();
                if (!(geometry instanceof NullGeometry)) {
                    
                    xml += "        <" + propertyName + ">\n";
                    xml += "            " + GMLFactory.createGMLNode(geometry).toString() + "\n";
                    xml += "        </" + propertyName + ">\n";
                }
            }
        }
        
        xml += "    </" + featureTypeName + ">\n";
        xml += "</wfs:Insert>\n";
        
        return xml;
    }
    
}