import nl.idgis.giclient.template.TemplateElement;
import nl.idgis.giclient.gis.GIS;
import nl.idgis.giclient.util.Strings;

/**
 * @author copierrj
 */
class nl.idgis.giclient.template.LabelElement extends TemplateElement {
	private var text:String = "";
	private var htmlText:String = "";
	private var fontSize:Number = 12;
	private var textFont:String = "Arial";
	private var autoSize:String = "left";
	private var background:Boolean = false;	
	private var vars:Object = null;
	
	public function LabelElement(gis:GIS) {
		super(gis);
		
		vars = new Object();
	}
	
	public function setParameter(name:String, value:Object):Void {
		super.setParameter(name, value);		
		
		vars[name] = "" + value;
	}
	
	public function doDrawElement(mc:MovieClip, handler:Object):Void {
		
		var format:TextFormat = new TextFormat();		
		format.size = fontSize;
   		format.font = textFont;
    	var textField:TextField = mc.createTextField("text", mc.getNextHighestDepth(), 0, 0, width, height);
		textField.setNewTextFormat(format);
		textField.autoSize = autoSize;
		textField.selectable = false;
		textField.background = background;
		if(htmlText != "") {
			textField.html = true;			
			var tmp:String =  Strings.replaceVars(htmlText, vars);			
			tmp = tmp.split("&lt;").join("<");
			tmp = tmp.split("&gt;").join(">");
			tmp = tmp.split("&apos;").join("'");
			textField.htmlText = tmp;
		} else {		
			textField.text = Strings.replaceVars(text, vars);
		}
		
		handler.onReady();
	}
}