import nl.idgis.giclient.template.TemplateElement;
import nl.idgis.giclient.gis.GIS;
import nl.idgis.giclient.framework.FrameWork;

/**
 * @author copierrj
 */
class nl.idgis.giclient.template.ImageElement extends TemplateElement {
	private var url:String = "";
	private var xscale:Number = 100;
	private var yscale:Number = 100;
	
	public function ImageElement(gis : GIS) {
		super(gis);
	}
	
	public function doDrawElement(mc:MovieClip, handler:Object):Void {		
		
		var image_handler:Object = new Object();
		image_handler.width = this.width;
		image_handler.height = this.height;
		image_handler.url = this.url;		 
		image_handler.onLoadInit = function(target_mc:MovieClip) 
		{
			var rWidth:Number = this.width / target_mc._width;
			var rHeight:Number = this.height / target_mc._height;
			
			var rSmallest:Number;
			if(rWidth < rHeight) {
				rSmallest = rWidth;				
			} else {
				rSmallest = rHeight;
			}
						
			target_mc._width *= rSmallest;
			target_mc._height *= rSmallest;
			
			handler.onReady();
		};
		image_handler.onLoadError = function(target_mc:MovieClip, errorCode:String, httpStatus:Number) {
			FrameWork(_root.frameWork).message(errorCode + ": " + this.url);
			handler.onReady();
		};
		
		var loader:MovieClipLoader = new MovieClipLoader();
		loader.addListener(image_handler);
		loader.loadClip(url, mc);
	}
}