/*----------------    FILE HEADER ---------------------------------------
 This file is part of Geoide.
 Copyright (C) 2005-2006 by:
 IDgis B.V.
 http://www.idgis.nl

 This library is free software; you can redistribute it and/or
 modify it under the terms of the GNU Lesser General Public
 License as published by the Free Software Foundation; either
 version 2.1 of the License, or (at your option) any later version.

 This library is distributed in the hope that it will be useful,
 but WITHOUT ANY WARRANTY; without even the implied warranty of
 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
 Lesser General Public License for more details.

 You should have received a copy of the GNU Lesser General Public
 License along with this library; if not, write to the Free Software
 Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307 USA

 Contact:

 Herman Assink
 IDgis bv
 P.O. Box 15
 7450 AA Holten
 The Netherlands
 E-Mail: herman.assink@idgis.nl

 * @version 1.4.0
 * @author IDgis team
 * 
 ------------------------------------------------------------------------*/

import nl.idgis.giclient.geoma.LinearRing;
import nl.idgis.giclient.geoma.Point;
import nl.idgis.giclient.geoma.Polygon;

class nl.idgis.giclient.geoma.Circle extends Polygon {

    private var numPoints:Number = 100; // Actual number of points in ring will be 1 more, because first/last point will occur twice.
    private var centerPoint:Point = null;

    function Circle(srsName:String, exteriorRing: LinearRing) {    	
        super(srsName, exteriorRing);
        centerPoint = super.getCenterPoint();
    }

    function addPoint(point:Point):Void {
    }

    function addPointN(point:Point):Void {
    }

    function removePoint(point:Point):Void {
    }

    function setPointXY(x:Number, y:Number):Void {
        var radiusPoint:Point = Point(exteriorRing.getPoints()[0]);
        radiusPoint.setXY(x, y);

        var centerPoint:Point = getCenterPoint();
        var radius:Number = getRadius();
        var angle:Number = getAngle();

        var points:Array = new Array(radiusPoint, radiusPoint);
        var linearRing:LinearRing = new LinearRing(getSRS(), points);
        var dx:Number = -1;
        var dy:Number = -1;
        var xpoint:Number = -1;
        var ypoint:Number = -1;
        for (var i:Number = 1; i < numPoints; i++) {
            dx = radius * Math.cos((2 * Math.PI) * i * (1 / numPoints) + angle);
            dy = radius * Math.sin((2 * Math.PI) * i * (1 / numPoints) + angle);
            xpoint = centerPoint.getX() + dx;
            ypoint = centerPoint.getY() + dy;
            linearRing.addPoint(new Point(getSRS(), xpoint, ypoint));
        }
        linearRing.setSuperGeometry(this);
        exteriorRing = linearRing;

      //  geometryEventDispatcher.changeGeometry(this, permanent);
    }

    function move(dx:Number, dy:Number):Void {
        super.move(dx, dy);
        centerPoint.move(dx, dy);
    }

    function getCenterPoint():Point {
        return centerPoint;
    }

    function setRadius(radius:Number, permanent:Boolean):Void {
        var centerPoint:Point = getCenterPoint();
        setPointXY(centerPoint.getX() + radius, centerPoint.getY());
    }

    function getRadius():Number{
        var radiusPoint:Point = Point(exteriorRing.getPoints()[0]);
        var centerPoint:Point = getCenterPoint();
        var distanceX:Number = radiusPoint.getX() - centerPoint.getX();
        var distanceY:Number = radiusPoint.getY() - centerPoint.getY();
        var radius:Number = Math.sqrt((distanceX * distanceX) + (distanceY * distanceY));
        //if (radius < 1) {
        //    radius = 1;
        //}
        return radius;
    }

    function getAngle():Number {
        var radiusPoint:Point = Point(exteriorRing.getPoints()[0]);
        var centerPoint:Point = getCenterPoint();
        var dx:Number = radiusPoint.getX() - centerPoint.getX();
        var dy:Number = radiusPoint.getY() - centerPoint.getY();
        var angle:Number = Math.atan2(dy, dx);

        return angle;
    }

    function clone():Circle {
        var extRing:LinearRing = getExteriorRing();
        var cloneRing:LinearRing = extRing.clone();
        return new Circle(getSRS(), cloneRing);
    }

}