package forms.queryAspect
{
	import core.AbstractController;

	public class QueryAspectController extends AbstractController
	{
		private function get queryAspectModel() : QueryAspectModel {
			return _model as QueryAspectModel;
		}
		
		public function afterServerChange() : void {
			setModelMember("serverLayer", null, false);
		} 
		
		public function afterServerLayerChange() : void {
			var serverLayer:XML = queryAspectModel.serverLayer;
			
			if(serverLayer) {
				var name:XMLList = serverLayer.child("Name");
					
				if(name.length() == 0) {
					name = serverLayer.child(new QName("http://www.opengis.net/wfs", "Name"));
				}
				
				var layerName:String;
				if(name.length() == 0) {
					layerName = serverLayer.toString();
				} else {
					layerName = name[0].toString();
				}
				
				if(layerName.indexOf(":") != -1) {
					layerName = layerName.split(":")[1];
				}
				
				if(emptyStringCheck(queryAspectModel.name)) {
					setModelMember('name', layerName);
				}
				
				for each(var title:Object in queryAspectModel.titles) {
					if(emptyStringCheck(title.title)) {
						addModelMember('titles', {language: title.language, title: layerName});
					} 
				}
			}
		}
		
		public function checkName(newName:Object) : String {
			var retval:String = emptyStringCheck(newName);
			if(retval) {
				return retval;
			}
			
			for each(var queryAspect:XML in queryAspectModel.dataSource.queryAspects.source.
				(@id != queryAspectModel.id && @clientId != queryAspectModel.clientId)) {
				if(queryAspect.Name == newName) {
					setModelMember("name", newName, false);
					return resourceManager.getString('abstractController', 'Msg_NameNotUnique');
				}		
			}
			
			return null;
		}
		
		public function checkServer(item:Object) : String {
			return inXMLListCheck(item, queryAspectModel.validServers);	
		}
		
		public function checkServerLayer(item:Object) : String {
			return inXMLListCheck(item, queryAspectModel.validServerLayers);	
		}
	}
}